; Installer script for MREKO
; $VER: Install MREKO 39.3 (9.2.97)

(complete 0)

(set #l-dest "LIBS:DataTypes/")
(set #permanent-dest "DEVS:DataTypes/")
(set #default-dest "SYS:Storage/DataTypes/")

(set #dt "Libs/DataTypes/reko.datatype")
(set #recog "Devs/DataTypes/")

; ***************************************************************************
; English strings

(set #bad-kick
	(cat "You must have AmigaDOS 3.0 or higher to use MREKO!"))

(set #welcome
	(cat "\nMREKO installation\n\n\n"
       "This script installs MREKO 1.2\n"
       "on your Amiga.\n\n\n\n"
       "MREKO is\n"
       "Copyright  1995-97 Michal Letowski\n"
       "All rights reserved.\n\n"))

(set #where-driver
	(cat "Should MREKO be installed permanently?"))

(set #where-help
	(cat "\nDataTypes can be installed as Permanently Enabled"
	     " or Manually Selectable.\n"
       "Pemanently Enabled means that the DataType is always"
       " ready for use.\n"
       "Manually Selectable means that the datatype has to be"
       " run before it can be used.\n"))

(set #dt-prompt
	(cat "Copying shared library"))

(set #recog-prompt
	(cat "Copying recognition files"))

; ***************************************************************************
; Install MREKO

; Check AmigaDOS version
(set #version (/ (getversion) 65536))
(if (< #version 39)
	(
		(abort #bad-kick)
	)
)

(message #welcome)

(welcome)
(set old_level @user-level)

(user 2)
(set #perm
	(askbool
		(prompt #where-driver)
		(help #where-help)
		(default 0))
)
(if #perm
	(set #recog-dest #permanent-dest)
	(set #recog-dest #default-dest)
)

; Do copy
(user old_level)

; Copy library
(copylib
	(prompt #dt-prompt)
	(help @copylib-help)
	(source #dt)
	(dest #l-dest)
	(confirm)
	(optional "nofail")
)
(complete 40)

; Copy recog
(copyfiles
	(prompt #recog-prompt)
	(help @copyfiles-help)
	(source #recog)
	(dest #recog-dest)
	(confirm)
	(optional "nofail")
	(all)
)
(complete 80)

; Activate descriptors if Permanently enabled
(if #perm
	(run "AddDataTypes REFRESH")
)
(complete 100)

(set @default-dest "")
(exit)
